miragte.bat hinzugefügt

miragte.bat

@@ -0,0 +1,49 @@
+@echo off
+
+echo Deaktiviere und loesche pcvisit / caloa Dienste...
+:: Sucht nun nach pcvisit UND caloa Diensten, stoppt und loescht sie
+powershell -Command "Get-Service -Name '*pcvisit*', '*caloa*' -ErrorAction SilentlyContinue | ForEach-Object { Stop-Service -Name $_.Name -Force -ErrorAction SilentlyContinue; Set-Service -Name $_.Name -StartupType Disabled -ErrorAction SilentlyContinue; sc.exe delete $_.Name }" >nul 2>&1
+
+echo Beende restliche Prozesse...
+powershell -Command "Get-Process -Name '*pcvisit*', '*caloa*' -ErrorAction SilentlyContinue | Stop-Process -Force" >nul 2>&1
+
+echo Fuehre pcvisit Uninstaller aus...
+for /f "delims=" %%I in ('dir /b /s "%ProgramFiles(x86)%\pcvisit Software AG\*uninstall*.exe" 2^>nul') do (
+    "%%I" /S >nul 2>&1
+)
+for /f "delims=" %%I in ('dir /b /s "%ProgramFiles%\pcvisit Software AG\*uninstall*.exe" 2^>nul') do (
+    "%%I" /S >nul 2>&1
+)
+
+:: 10 Sekunden warten
+ping 127.0.0.1 -n 11 >nul
+
+echo Raeume pcvisit Datei-Reste auf...
+rmdir /S /Q "%ProgramFiles(x86)%\pcvisit Software AG" >nul 2>&1
+rmdir /S /Q "%ProgramFiles%\pcvisit Software AG" >nul 2>&1
+
+echo Lade RustDesk herunter...
+powershell -Command "$ProgressPreference = 'SilentlyContinue'; Invoke-WebRequest -Uri 'https://me-files.vmd55888.de/me-rustdesk-host.exe' -OutFile 'C:\TMP\rustdesk_installer.exe' -UseBasicParsing"
+
+:: 2 Sekunden warten (Ping-Trick)
+ping 127.0.0.1 -n 3 >nul
+
+
+echo Erstelle saubere Admin-Umgebung via Taskplaner...
+schtasks /create /tn "RustDesk_Setup" /ru "SYSTEM" /rl HIGHEST /tr "C:\TMP\rustdesk_installer.exe --silent-install" /sc once /st 00:00 /f >nul 2>&1
+
+echo Starte Installation...
+schtasks /run /tn "RustDesk_Setup" >nul 2>&1
+
+:: 15 Sekunden warten (Ping-Trick)
+ping 127.0.0.1 -n 16 >nul
+
+
+echo Raeume Task wieder auf...
+schtasks /delete /tn "RustDesk_Setup" /f >nul 2>&1
+
+echo Entferne Desktop-Verknuepfung...
+del "C:\Users\Public\Desktop\ME-RustDesk-Host.lnk" /Q /F >nul 2>&1
+
+
+echo Fertig!